Estructura repetitiva repeat/until

https://www.tutorialesprogramacionya.com/delphiya/detalleconcepto.php?punto=12&codigo=94&inicio=0 

12 - Estructura repetitiva repeat/until

La sentencia repeat es otra estructura repetitiva, la cual ejecuta al menos una vez su bloque repetitivo, a diferencia del while que podía no ejecutar el bloque.

Esta estructura repetitiva se utiliza cuando conocemos de antemano que por lo menos una vez se ejecutará el bloque repetitivo.
La condición de la estructura está abajo del bloque a repetir, a diferencia del while que está en la parte superior.

Finaliza la ejecución del bloque repetitivo cuando la condición retorna verdadero, es decir en forma inversa al while (repeat/until se lee repetir hasta que sea verdadero)

El bloque de operaciones se repite HASTA que la condición sea Verdadera.
Si la condición retorna Falso el bloque se repite nuevamente.

Es importante analizar y ver que las operaciones se ejecutan como mínimo una vez.

En el lenguaje Pascal/Delphi la estructura repeat la codificamos con la siguiente sintaxis:

repeat
    <Operación(es)>
until <Condición>;

No requiere que las instrucciones estén encerradas en un begin/end, debido que comienza con la palabra "repeat" y finaliza con la palabra "until".

Problema 1

Escribir un programa que solicite la carga de un número entre 0 y 999, y nos muestre un mensaje de cuántos dígitos tiene el mismo.
Finalizar el programa cuando se cargue el valor 0.

Diagrama de flujo:

No hay que confundir los rombos de las estructuras condicionales con los de las estructuras repetitivas repeat.

En este problema por lo menos se carga un valor. Si se carga un valor mayor o igual a 100 se trata de un número de tres cifras, si es mayor o igual a 10 se trata de un valor de dos dígitos, en caso contrario se trata de un valor de un dígito. Este bloque se repite hasta que se ingresa en la variable valor el número 0 con lo que la condición de la estructura repeat retorna verdadero y sale del bloque repetitivo finalizando el programa.

Proyecto51

program Proyecto51;

{$APPTYPE CONSOLE}

var
  valor: Integer;

begin
  repeat
    Write('Ingrese un valor entre 0 y 999 - (Cero para finalizar):');
    ReadLn(valor);
    if valor >= 100 then
    begin
      WriteLn('El numero tiene 3 dígitos');
    end
    else
    begin
      if valor >= 10 then
      begin
        WriteLn('El numero tiene 2 dígitos');
      end
      else
      begin
        WriteLn('El numero tiene 1 dígito');
      end;
    end;
  until valor = 0;
  Write('Fin del programa');
  ReadLn;
end.

La ejecución del programa finaliza cuando en la variable "valor" se ingresa el valor 0, con dicho valor la condición del until retorna verdadero.

Problema 2

Escribir un programa que solicite la carga de números por teclado, obtener su promedio. Finalizar la carga de valores cuando se cargue el valor 0.

Cuando la finalización depende de algún valor ingresado por el operador conviene el empleo de la estructura repeat, por lo menos se cargará un valor (en el caso más extremo se carga 0, que indica la finalización de la carga de valores).

Diagrama de flujo:

Es importante analizar este diagrama de flujo. Definimos un contador cant que cuenta la cantidad de valores ingresados por el operador (no lo incrementa si ingresamos 0).
El valor 0 no es parte de la serie de valores que se deben sumar.
Definimos el acumulador suma que almacena todos los valores ingresados por teclado.

La estructura repetitiva repeat se repite hasta que ingresamos el valor 0. Con dicho valor la condición del until retorna verdadero y continúa con el flujo del diagrama.

Disponemos por último una estructura condicional para el caso que el operador cargue únicamente un 0 y por lo tanto no podemos calcular el promedio ya que no existe la división por 0.

En caso que el contador cant tenga un valor distinto a 0 el promedio se obtiene dividiendo el acumulador suma por el contador cant que tiene la cantidad de valores ingresados antes de introducir el 0.

Proyecto52

program Proyecto52;

{$APPTYPE CONSOLE}

{$R *.res}

var
  suma: Integer;
  cant: Integer;
  valor: Integer;
  promedio: Double;

begin
  suma := 0;
  cant := 0;
  repeat
    Write('Ingrese valor:');
    ReadLn(valor);
    if valor <> 0 then
    begin
      suma := suma + valor;
      cant := cant + 1;
    end;
  until valor = 0;
  if cant <> 0 then
  begin
    promedio := suma / cant;
    Write('El promedio es:', promedio:0:2);
  end
  else
  begin
    Write('No se ingresaron valores');
  end;
  ReadLn;
end.

El contador cant DEBE inicializarse antes del repeat, lo mismo que el acumulador suma.

El promedio se calcula siempre y cuando el contador cant sea distinto a 0.

Problema 3

Realizar un programa que permita ingresar el peso (en gramos) de piezas. El proceso termina cuando ingresamos el valor 0. Se debe informar:
a ) Cuántas piezas tienen un peso entre 98 gr. y 102 gr.?, cuántas con más de 102 gr.? y cuántas con menos de 98 gr.?
b ) La cantidad total de piezas procesadas.

Diagrama de flujo:

Los tres contadores cont1, cont2, y cont3 se inicializan en 0 antes de entrar a la estructura repetitiva.

A la variable suma no se la inicializa en 0 porque no es un acumulador, sino que guarda la suma del contenido de las variables cont1, cont2 y cont3.

La estructura se repite hasta que se ingresa el valor 0 en la variable peso. Este valor no se lo considera un peso menor a 98 gr., sino que indica que ha finalizado la carga de valores por teclado.

Proyecto53

program Proyecto53;

{$APPTYPE CONSOLE}

{$R *.res}

var
  cant1, cant2, cant3: Integer;
  suma: Integer;
  peso: Integer;

begin
  cant1 := 0;
  cant2 := 0;
  cant3 := 0;
  repeat
    Write('Ingrese peso:');
    ReadLn(peso);
    if peso > 102 then
    begin
      cant1 := cant1 + 1;
    end
    else
    begin
      if peso >= 98 then
      begin
        cant2 := cant2 + 1;
      end
      else
      begin
        if peso > 0 then
        begin
          cant3 := cant3 + 1;
        end;
      end;
    end;
  until Peso = 0;
  WriteLn;
  suma := cant1 + cant2 + cant3;
  WriteLn('Piezas con peso superior a 102 gr. :', cant1);
  WriteLn('Piezas con peso superior o igual a 98 gr. y menor o igual a 102 gr.:', cant2);
  WriteLn('Piezas con peso inferior a 98 gr. :', cant3);
  WriteLn;
  WriteLn('Cantidad de piezas procesadas:', suma);
  ReadLn;
end.

Problema 4

Realizar un programa que solicite cargar el nombre de un alumno, sus tres notas, calcule el promedio e imprima alguno de los siguientes comentarios:

Si el promedio < 4 		: ' Reprobado '.
Si promedio>=4 y promedio<7 	: ' Recupera '.
Si el promedio>=7 		: ' Aprobado '.

Imprimir el nombre de los alumnos Aprobados.

El proceso debe repetirse hasta que se conteste 'no' a la pregunta 'Desea ingresar otro juego de notas para procesarlas ?'.

Diagrama de flujo:

Los tres contadores cont1, cont2, y cont3 se inicializan en 0 antes de entrar a la estructura repetitiva.

A la variable suma no se la inicializa en 0 porque no es un acumulador, sino que guarda la suma del contenido de las variables cont1, cont2 y cont3.

La estructura se repite hasta que se ingresa el valor 0 en la variable peso. Este valor no se lo considera un peso menor a 98 gr., sino que indica que ha finalizado la carga de valores por teclado.

Proyecto54

program Proyecto54;

{$APPTYPE CONSOLE}

{$R *.res}

var
  nota1: Integer;
  nota2: Integer;
  nota3: Integer;
  nombre: String;
  opcion: String;
  promedio: Double;

begin
  repeat
    Write('Ingrese el nombre:');
    ReadLn(nombre);
    Write('Primer nota:');
    ReadLn(nota1);
    Write('Segunda nota:');
    ReadLn(nota2);
    Write('Tercer nota:');
    ReadLn(nota3);
    promedio := (nota1 + nota2 + nota3) / 3;
    if promedio >= 7 then
    begin
      WriteLn('Nombre del alumno:', nombre);
      WriteLn('Aprobado');
    end
    else
    begin
      if promedio >= 4 then
      begin
        WriteLn('Recupera');
      end
      else
      begin
        WriteLn('Reprobado');
      end;
    end;
    WriteLn;
    WriteLn;
    Write('Desea ingresar otro juego de notas (si/no) ?');
    ReadLn(opcion);
  Until Opcion = 'no';
end.

Para guardar cadenas de caracteres en Pascal/Delphi debemos definir variables de tipo String:

  nombre: String;
  opcion: String;

Las variables de tipo String también las cargamos con el procedimiento ReadLn:

    Write('Desea ingresar otro juego de notas (si/no) ?');
    ReadLn(opcion);

Los operadores relacionales también funcionan con las variables de tipo String:

  Until Opcion = 'no';

Es importante notar que si se ingresa por teclado en mayúsculas la cadena 'NO' luego el operador = verifica que no son iguales.

Problemas propuestos

• Realizar un programa que acumule (sume) valores ingresados por teclado hasta ingresar el 9999 (no sumar dicho valor, indica que ha finalizado la carga). Imprimir el valor acumulado e informar si dicho valor es cero, mayor a cero o menor a cero.
• En un banco se procesan datos de las cuentas corrientes de sus clientes. De cada cuenta corriente se conoce: número de cuenta y saldo actual. El ingreso de datos debe finalizar al ingresar un valor negativo en el número de cuenta.
  Se pide confeccionar un programa que lea los datos de las cuentas corrientes e informe:
  a)De cada cuenta: número de cuenta y estado de la cuenta según su saldo, sabiendo que:
  

  Estado de la cuenta	'Acreedor' si el saldo es >0.
  			'Deudor' si el saldo es <0.
  			'Nulo' si el saldo es =0.
  

  b) La suma total de los saldos acreedores.
• Se realizó un censo provincial y se desea procesar la información obtenida en dicho censo.
  De cada una de las personas censadas se tiene la siguiente información: número de documento, edad y genero ('femenino' o 'masculino').
  Se pide confeccionar un programa que lea los datos de cada persona censada (para finalizar ingresar el valor cero en el número de documento) e informar:
  a) Cantidad total de personas censadas.
  b) Cantidad de varones.
  c) Cantidad de mujeres.
  d) Cantidad de varones cuya edad varía entre 16 y 65 años.

Solución

Retornar